SVWS-Server + Schild3 unter Win11

[Hauke Hayen]

Können Sie in localhost/admin migrieren und das vollständige logfile sichern?
Mit Hilfe dieses files haben wir kürzlich eine Inkonsistenz unserer mdb gefunden, obwohl die auch schon mehrfach zuvor fehlerfrei migriert wurde. Es hatte sich in einer Tabelle eine Leerzeile eingeschmuggelt.

[Falko Müller]

Installation läuft durch bis zur Migration der DB, die "dauert" aber nicht einmal eine Sekunde, wird also gar nicht migriert, Meldung Installation fertig...

Genau dieses Problem hatte ich gestern auf meinem Win10 Rechner. Ich habe dann zunächst im Browser den localhost aufgerufen. Es wurde eine Verbindung hergestellt, allerdings wurde nur das Schema "Standarddatenbank" angeboten, das ich gar nicht eingetragen hatte. Beim Aufruf von localhost/admin erschien nur eine weiße Seite.

Bei den zahlreichen Installations- und Deinstallationsversuchen ist mir dann aufgefallen, dass die Batch nach jeder Zeile sinngemäß meldete, dass der entsprechende Dienst oder Schlüssel auf dem Rechner nicht gefunden wurde. Ich bin daher die einzelnen Schritte der Batch manuell durchgegangen und habe tatsächlich in der Registry noch zwei der Einträge gefungen, die durch die Batch eigentlich entfernt werden sollten. Nachdem ich diese Einträge gelöscht hatte, lief die Installation promblemlos korrekt durch.

[Hauke Hayen]

Genau das meinte ich hier:

viewtopic.php?p=42163#p42163

Die batch lässt ein paar Reste stehen...

[Raffenberg]

Ich benutze immer folgende Batch-Datei und führe diese als Admin aus, um eine Client-Testinstallation zu entfernen:

Code: Alles auswählen

::Die Bildschirmausgabe wird sinnvoll reduziert
@echo OFF

::Abfrage, ob die Batchdatei im Admin-Modus gestartet wurde
echo ---------------------------------------------------------------------------------
echo Bitte schliessen Sie das Fenster, wenn die Batch-Datei nicht im 
echo Administratormodus gestartet wurde. Dateien koennen sonst nicht geloescht werden.
echo ---------------------------------------------------------------------------------
echo.

::Auf Wunsch wird das komplette SVWS-Arbeitsverzeichnis entfernt. Andernfalls werden nur die Connection-Files im Arbeitsverzeichnis gelöscht.
echo -------------------------------------------------------------------
set /p ergeb=Soll das SVWS-Arbeitsverzeichnis ebenfalls geloescht werden [j/n]
echo -------------------------------------------------------------------

echo.
echo ----------------------------------------------------------------------------------
echo Die Batchdatei zum loeschen des SVWS-Servers und SchILD-NRW3 wird nun ausgefuehrt
echo ----------------------------------------------------------------------------------

timeout /T 2

::Stoppt den SVWS-Server, falls dieser ausgeführt wird (Hintergrunddienst
sc stop svws_server_service

::Stoppt die MariaDB, falls diese ausgeführt wird (Hintergrunddienst)
sc stop svws_server_mariadb

::Pause, um sicherzustellen, dass die Dienste vom Betriebssystem in Ruhe beendet werden können
timeout /T 5

::Entfernt den SVWS-Server (Hintergrunddienst)
sc delete svws_server_service

::Entfernt die MariaDB (Hintergrunddienst)
sc delete svws_server_mariadb


::Entfernt die Einträge des SVWS-Servers in der Registry
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\SVWSServer" /va  /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\SVWS Server_is1" /va /f

::Entfernt die Einträge von SchILD-NRW3 in der Registry
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\SchILD-NRW3_is1" /va /f
reg delete "HKEY_CURRENT_USER\Software\Schild3000" /va /f

::Pause, um sicherzustellen, dass die Einträge in der Registry vom Betriebssystem in Ruhe entfernt werden können
timeout /T 8

::Löscht den Installationsordner der MariaDB des SVWS-Servers
rmdir /S /Q "C:\ProgramData\SVWS-Server"

::Löscht den Installationsordner des SVWS-Servers
rmdir /S /Q "C:\Programme\SVWS-Server"

::Löscht den Installationsordner von SchILD-NRW3
rmdir /S /Q "C:\Program Files (x86)\SchILD-NRW3"

::Je nach Eingabe wird nun das SVWS-Arbeitsverzeichnis komplett gelöscht, oder nur die Connection-Files
if /i "%ergeb%" == "j" (
	rmdir /S /Q "C:\SVWS-Arbeitsverzeichnis"
	echo.
	echo ------------------------------------------------------------------------------
	echo Das SVWS-Arbeitsverzeichnis, der SVWS-Server und SchILD-NRW3 wurden entfernt.
	echo ------------------------------------------------------------------------------
) else (
	del /F /Q "C:\SVWS-Arbeitsverzeichnis\Connection-Files\*.con"
	echo.
	echo --------------------------------------------------------------------------------------------------
	echo Die Connection-Files im SVWS-Arbeitsverzeichnis, der SVWS-Server und SchILD-NRW3 wurden entfernt.
	echo --------------------------------------------------------------------------------------------------
)

timeout /T 7